場の異常

場の異常測定器

異常な場所では理論も狂う?

ずいぶん前の話ですが、井村宏治先生が「霊などという異常なものが出るところは世の中の因果律も狂っているのではないだろうか。」とお考えになりました。

試しにポケコンで乱数を発生させたところ発生の仕方に偏りがあったということです。ポケコンで発生する乱数は、計算式により作り出す擬似乱数です。どこでやっても偏りがあることは、ないはずです。ところが、計算結果が場所により変わることがあったということなのです。

乱数もゆがむ(ポケコン版)

この話で聞いて作ったのが下のポケコン(Sharp E-650用)プログラムでした。
あちこちで使われてます。
あの帽子かぶった嘘つきおじさんも愛用してます。

もしポケコンをお持ちならがんばって入力してみるのもよろしいかと思います。(某会社で「場の測定・空間異常検知」ができると売り出しているプログラムの原型です。中身わかってのかな?USOという番組でも2002/1/26に放送されました。)

10 '----- Field check --------
 20 *START
 30 CLS :RANDOMIZE :H=0
 40 PRINT "** Field Check program **"
 50 LOCATE 22:PRINT "T.Takao"
 60 LL=500 :UL=100000
 70 LOCATE 0,3:PRINT "Specify over ";LL
 80 LOCATE 31,3:PRINT "TOP=[Q]+ "
 90 GCURSOR (6*39 ,8*4):GPRINT "2070F8203F"
 100 A$=""
 110 LOCATE 0,2:INPUT "How many trial times==> ";A$
 120 IF A$="Q" THEN END
 130 N=VAL A$
 140 IF N<LL THEN N=LL
 150 IF N>UL THEN N=UL
 160 GOSUB *GINIT
 170 *K4:IF INKEY$ <>"" THEN *K4
 180 FOR S=1 TO N
 190 A=RND 0*2:B=INT (A)
 200 GOSUB *GPUT
 210 IF B=0 GOTO 270
 220 H=H+1
 230 A$=INKEY$
 240 IF (A$= CHR$ 81) THEN
 250 S=N
 260 ENDIF
 270 NEXT S
 280 CR=(H-N/2)/SQR (N/4):Z=ABS (CR)
 290 BEEP 3:LOCATE 0,3
 310 IF Z>=2.58 THEN MSG$="Level 5(99)":GOTO *PRT
 320 IF Z>=1.96 THEN MSG$="Level 4(95)":GOTO *PRT
 330 IF Z>=1.65 THEN MSG$="Level 3(90)":GOTO *PRT
 340 IF Z>=1.28 THEN MSG$="Level 2(80)":GOTO *PRT
 350 IF Z>=1.03 THEN MSG$="Level 1(70)":GOTO *PRT
 360 MSG$="OK. No problem."
 370 *PRT
 380 PRINT MSG$;
 390 LPRINT MSG$
 400 PRINT USING "      0:##,### 1:##,###";N-H,H
 410 LPRINT USING "0:##,### 1:##,###";N-H,H
 420 LPRINT "-----------------"
 430 GOSUB *GETKEY
 440 CLS :GOTO *START
 450 END
 460 *GINIT
 470 CLS :F=0
 480 IF N<2000 THEN K=10 ELSE K=INT (N/220)
 490 LINE (0,11)-(239,11)
 500 LINE (19,0)-(19,23)
 510 LOCATE 1,0:PRINT "0"
 520 LOCATE 1,2:PRINT "1"
 530 RETURN
 540 *GPUT
 550 E=INT ((S/N)*220)
 560 IF F=E THEN GOTO *P1
 570 G0=0:G1=0:RANDOMIZE :PRESET (19+E,11)
 580 *P1
 590 IF B=0 THEN G0=G0+1:PSET (20+E,11-INT ((G0/K)*10))
 600 IF B=1 THEN G1=G1+1:PSET (20+E,11+INT ((G1/K)*10))
 610 LOCATE 0,3:PRINT USING "Trial times:##,###    0:##,### 1:##,###";N,S-H,H
 620 F=E:RETURN
 630 *GETKEY
 640 *K1:IF INKEY$ <>"" THEN *K1
 650 *K2:A$=INKEY$ :IF A$="" THEN *K2
 660 RETURN

私もITエンジニアです。乱数は擬似乱数であることは百も承知です。

しかし、幾多の人のテストにより確かに霊の出るようなところでは上のプログラムで偏りが見出されることがある、という結果が得られているのは事実です。
事実を「そんなはずはない」と断言し、多くの人より俺は頭がいいと言い切るほど私は賢くないです。
しかし最近はWindowsの時代です。みなさんに遊んでもらうわけにはいきません。

この件、別の方法で製品化検討中(2014冬までには発表したい)

投稿者: たかお

毎度、お世話になってます。店主です。

コメントを残す